asp下制做行背景颜色交替变换的表格

1. <%  
2. Const adInteger = 3  
3. Const adVarChar = 200   
4. ' 声明变量  
5. Dim myRecordset   
6. Dim iLetter       
7. Dim Field         
8. Dim strAltColor   
9. Dim bColor        
10. bColor = False  
11.  
12. ' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。  
13. Set myRecordset = Server.CreateObject("ADODB.Recordset")  
14. myRecordset.Fields.Append "ID", adInteger  
15. myRecordset.Fields.Append "Title", adVarChar, 25  
16. myRecordset.Fields.Append "Description", adVarChar, 255  
17.  
18. myRecordset.Open  
19.  
20. ' Fill RS with sample data:  
21. For iLetter = Asc("A") To Asc("M")  
22.  myRecordset.AddNew  
23.  myRecordset.Fields("ID").Value          = iLetter - 64  
24.  myRecordset.Fields("Title").Value       = "字母：" & Chr(iLetter)  
25.  myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."  
26.  myRecordset.Update  
27. Next 'iLetter  
28.  
29. '移动到头部开始位置，以便下面的循环开始.  
30. myRecordset.MoveFirst  
31.  
32.  
33. ' 在表格中显示数据  
34.  
35. Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf  
36.  
37. '表头  
38. Response.Write vbTab & "<tr>" & vbCrLf  
39. For Each Field in myRecordset.Fields  
40.  Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"  
41.  Response.Write Field.Name  
42.  Response.Write "</strong></td>" & vbCrLf  
43. Next 'Field  
44. Response.Write vbTab & "</tr>" & vbCrLf  
45.  
46. Do While Not myRecordset.EOF  
47.  ' 循环改变单元格的背景颜色  
48.  bColor = Not bColor  
49.  If bColor Then  
50.   strAltColor = "#FFFFFF"  
51.  Else  
52.   strAltColor = "#FF8040"  
53.  End If  
54.  
55.  '循环改变单元格的背景颜色  
56.  Response.Write vbTab & "<tr>" & vbCrLf  
57.  For Each Field in myRecordset.Fields  
58.   Response.Write vbTab & vbTab & "<td bgcolor="""  
59.   Response.Write strAltColor  
60.   Response.Write """>" & Field.Value & "</td>" & vbCrLf  
61.  Next 'Field  
62.  Response.Write vbTab & "</tr>" & vbCrLf  
63.  
64.  myRecordset.MoveNext  
65. Loop  
66.  
67. ' End the table  
68. Response.Write "</table>" & vbCrLf  
69.  
70. ' 关闭对象、释放资源  
71. myRecordset.Close  
72. Set myRecordset = Nothing  
73. %>