1）实验平台：正点原子MPSoC开发板
2）平台购买地址：https://detail.tmall.com/item.htm?id=692450874670
3）全套实验源码+手册+视频下载地址： http://www.openedv.com/thread-340252-1-1.html
第十七章 呼吸灯实验
呼吸灯最早由苹果公司发明并应用于笔记本睡眠提示上，其一经展出，立刻吸引众多科技厂商争相效仿，并广泛用于各种电子产品中，尤其是智能手机。呼吸灯其实是在微处理器的控制下，由暗渐亮、然后再由亮渐暗，模仿人呼吸方式的LED灯。
本章分为以下几个章节：
81010.1呼吸灯简介
10.2实验任务
10.3硬件设计
10.4程序设计
10.5下载验证
10.1呼吸灯简介
呼吸灯采用PWM的方式，在固定的频率下，通过调整占空比的方式来控制LED灯亮度的变化。PWM（Pulse Width Modulation），即脉冲宽度调制，它利用微处理器输出的PWM信号，实现对模拟电路控制的一种非常有效的技术，广泛应用于测量、通信、功率控制等领域。
在由计数器产生的固定周期的PWM信号下，如果其占空比为0，则LED灯不亮；如果其占空比为100%，则LED灯最亮。所以将占空比从0到100%，再从100%到0不断变化，就可以实现LED灯的“呼吸”效果。
PWM占空比调节示意图如下图所示：
图 10.1.1 呼吸灯PWM占空比示意图
由上图可知，LED高电平的时间由长渐渐变短，再由短渐渐变长，如果LED灯是高电平点亮，则LED灯会呈现出亮度由亮到暗，再由暗到亮的过程。
10.2实验任务
本节实验任务是使用正点原子DFZU2EG/4EV MPSoC开发板上的PL LED1，实现呼吸灯的效果，即由灭渐亮，然后再由亮渐灭。
10.3硬件设计
发光二极管的原理图如下图所示，其阴极通过330欧姆的电阻连到地（GND），阳极与ZYNQ的IO相连，LED与地之间的电阻起到限流作用。当PL_LED1输出高电平时，点亮LED灯，当PL LED1输出低电平时，LED灯熄灭。
图 10.3.1 呼吸灯硬件原理图
本实验中，系统时钟、按键复位以及LED端口的管脚分配如下表所示：
表 10.3.1 呼吸灯实验管脚分配
信号名 方向 管脚 端口说明 电平标准
sys_clk_p input AE5 系统差分输入时钟 DIFF_HSTL_I_12
sys_clk_n input AF5 系统差分输入时钟 DIFF_HSTL_I_12
sys_rst_n input AH11 PL复位按键，低有效 LVCMOS33
led output AE10 PL LED1 LVCMOS33
对应的XDC约束语句如下所示：
#IO管脚约束
#时钟周期约束
create_clock -name sys_clk_p -period 10.000 [get_ports sys_clk_p]
#时钟
set_property IOSTANDARD DIFF_HSTL_I_12 [get_ports sys_clk_p]
set_property IOSTANDARD DIFF_HSTL_I_12 [get_ports sys_clk_n]
set_property PACKAGE_PIN AE5 [get_ports sys_clk_p]
set_property PACKAGE_PIN AF5 [get_ports sys_clk_n]
#复位
set_property -dict {PACKAGE_PIN AH11 IOSTANDARD LVCMOS33} [get_ports sys_rst_n]
#LED灯
set_property -dict {PACKAGE_PIN AE10 IOSTANDARD LVCMOS33} [get_ports led]
10.4程序设计
本次实验的模块端口及结构框图如下图所示。
图 10.4.1 模块端口及信号连接图
周期信号计数器用于产生驱动LED的脉冲信号，本次实验的周期信号频率为1Khz，其占空比由后级逻辑在每个周期之后进行递增或递减，最后再对当前计数值和占空比计数值进行比较，以输出占空比可调的脉冲信号。
呼吸灯代码如下：
1 module breath_led(
2 input sys_clk_p, //系统差分输入时钟
3 input sys_clk_n, //系统差分输入时钟
4 input sys_rst_n, //复位信号
5
6 output led //LED
7 );
8
9 //reg define
10 reg [16:0] period_cnt ; //周期计数器频率：1khz 周期:1ms 计数值:1ms/10ns=100000
11 reg [16:0] duty_cycle ; //占空比数值
12 reg inc_dec_flag ; //0 递增 1 递减
13
14 //*****************************************************
15 //** main code
16 //*****************************************************
17
18 //转换差分信号
19 IBUFDS diff_clock
20 (
21 .I (sys_clk_p), //系统差分输入时钟
22 .IB(sys_clk_n), //系统差分输入时钟
23 .O (sys_clk) //输出系统时钟
24 );
25
26 //根据占空比和计数值之间的大小关系来输出LED
27 assign led = (period_cnt >= duty_cycle) ? 1'b1 : 1'b0;
28
29 //周期计数器
30 always @(posedge sys_clk or negedge sys_rst_n) begin
31 if(!sys_rst_n)
32 period_cnt <= 17'd0;
33 else if(period_cnt == 17'd100000)
34 period_cnt <= 17'd0;
35 else
36 period_cnt <= period_cnt + 1'b1;
37 end
38
39 //在周期计数器的节拍下递增或递减占空比
40 always @(posedge sys_clk or negedge sys_rst_n) begin
41 if(!sys_rst_n) begin
42 duty_cycle <= 17'd0;
43 inc_dec_flag <= 1'b0;
44 end
45 else begin
46 if(period_cnt == 17'd100000) begin //计满1ms
47 if(inc_dec_flag == 1'b0) begin //占空比递增状态
48 if(duty_cycle == 17'd100000) //如果占空比已递增至最大
49 inc_dec_flag <= 1'b1; //则占空比开始递减
50 else //否则占空比以50为单位递增
51 duty_cycle <= duty_cycle + 17'd50;
52 end
53 else begin //占空比递减状态
54 if(duty_cycle == 17'd0) //如果占空比已递减至0
55 inc_dec_flag <= 1'b0; //则占空比开始递增
56 else //否则占空比以50为单位递减
57 duty_cycle <= duty_cycle - 17'd50;
58 end
59 end
60 end
61 end
62
63 endmodule
第30-37行是1KHz周期信号的计数器，用于产生1KHz的LED驱动信号。第31-52行的always块为占空比设定模块，每次计数完了一个周期，就根据递增/递减标志来对占空比计数值（duty_cycle）进行递增/递减50个计数值，这个递增或者递减的数值大小可以用来控制呼吸灯的呼吸频率。
如果占空比计数值（duty_cycle）已经递增到了最大，则呼吸灯已经处于最亮的状态，接下来开始递减；反之，如果占空比计数至已经递减到了最小，即0，则呼吸灯处于熄灭的状态，接下来开始递增；如此循环往复，最终实现了流水灯的效果。
在代码的第27行通过组合逻辑把当前的周期计数值和占空比计数值进行比较，来判断LED的输出电平。在一个周期内，如果当前的周期计数值小于等于占空比计数值，则LED输出高电平，即点亮；如果当前的周期计数值大于占空比计数值，则LED输出低电平，即熄灭。
10.5下载验证
编译工程并生成比特流.bit文件。将下载器一端连接电脑，另一端与开发板上的JTAG下载口连接，然后连接电源线，最后将开发板的电源拨码开关按键往电源指示灯的方向拨动对开发板进行上电，上电成功后开发板的电源指示灯会亮蓝灯。
点击Vivado左侧“Flow Navigator”窗口最下面的“Open Hardware Manager”，此时Vivado软件识别到下载器，点击“Hardware”窗口中“Progam Device”下载程序，在弹出的界面中选择“Program”下载程序。
程序下载完成后，可以看到开发板的PL LED1灯由暗慢慢变亮，再由亮慢慢变暗，即呈现出“呼吸”的效果，如下图所示：
图 10.5.1 开发板实验现象