1、创建发送邮件的存储过程
CREATE OR REPLACE PROCEDURE send_mail(p_recipient VARCHAR2, -- 邮件接收人
p_subject VARCHAR2, -- 邮件标题
p_message VARCHAR2 -- 邮件正文
) IS
--下面四个变量请根据实际邮件服务器进行赋值
v_mailhost VARCHAR2(30) := '123.125.50.135'; --SMTP服务器地址
v_user VARCHAR2(30) := '******'; --登录SMTP服务器的用户名
v_pass VARCHAR2(20) := '******'; --登录SMTP服务器的密码
v_sender VARCHAR2(50) := '******@163.com'; --发送者邮箱，一般与 ps_user 对应
v_conn UTL_SMTP.connection; --到邮件服务器的连接
v_msg varchar2(4000); --邮件内容
BEGIN
v_conn := UTL_SMTP.open_connection(v_mailhost, 25);
UTL_SMTP.ehlo(v_conn, v_mailhost); --是用 ehlo() 而不是 helo() 函数
--否则会报：ORA-29279: SMTP 永久性错误: 503 5.5.2 Send hello first.
UTL_SMTP.command(v_conn, 'AUTH LOGIN'); -- smtp服务器登录校验
UTL_SMTP.command(v_conn,
UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));
UTL_SMTP.command(v_conn,
UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));
UTL_SMTP.mail(v_conn, '<' || v_sender || '>'); --设置发件人
UTL_SMTP.rcpt(v_conn, '<' || p_recipient || '>'); --设置收件人
-- 创建要发送的邮件内容 注意报头信息和邮件正文之间要空一行
v_msg := 'Date:' || TO_CHAR(SYSDATE, 'yyyy mm dd hh24:mi:ss') ||
UTL_TCP.CRLF || 'From: ' || v_sender || '' || UTL_TCP.CRLF ||
'To: ' || p_recipient || '' || UTL_TCP.CRLF || 'Subject: ' ||
p_subject || UTL_TCP.CRLF || UTL_TCP.CRLF -- 这前面是报头信息
|| p_message; -- 这个是邮件正文
UTL_SMTP.open_data(v_conn); --打开流
UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg)); --这样写标题和内容都能用中文
UTL_SMTP.close_data(v_conn); --关闭流
UTL_SMTP.quit(v_conn); --关闭连接
EXCEPTION
WHEN OTHERS THEN
DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);
DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);
END send_mail;
2、创建完存储过程需要配置额外的权限（创建的步骤不能错）
begin
dbms_network_acl_admin.create_acl (
acl => 'sendmail.xml', ---创建的访问控制列表名字
description => 'Normal Access',
principal => 'CONNECT',
is_grant => TRUE,
privilege => 'connect',
start_date => null,
end_date => null
);
end;
----------------------------------------------------------------
begin
dbms_network_acl_admin.add_privilege(acl => 'sendmail.xml',
principal => 'ABS_20160104',
is_grant => TRUE,
privilege => 'connect',
start_date => null,
end_date => null);
end;
----------------------------------------------------------------
begin
dbms_network_acl_admin.assign_acl (
acl => 'utlpkg.xml',
host => '123.125.50.135', --可访问服务器的地址
lower_port => 25, ---最低端口
upper_port => 25); --最高端口
end;
----------------------------------------------------------------
--删除权限文件
BEGIN
DBMS_NETWORK_ACL_ADMIN.drop_acl(acl => 'sendmail.xml');
COMMIT;
END;
--查询全限文件
SELECT * FROM resource_view WHERE any_path like '/sys/acls/%.xml';
--查询文件网络权限
SELECT host, lower_port, upper_port, acl FROM dba_network_acls;
--查询用户的网络权限
SELECT acl,
principal,
privilege,
is_grant,
TO_CHAR(start_date, 'DD-MON-YYYY') AS start_date,
TO_CHAR(end_date, 'DD-MON-YYYY') AS end_date
FROM dba_network_acl_privileges;
现在可以调用存储过程发送邮件。