[Box2D]让刚体听我的——ApplyForce、ApplyImpulse、SetLinearVelocity

时间：2021-09-16 20:05:13

出自：http://bbs.9ria.com/thread-135588-1-1.html


对于大部分游戏来说，允许玩家控制游戏对象，是个非常基本的特性。而到目前为止，在学到的Box2D技巧中，创建了刚体之后，我们只能眼睁睁的看着它*落体。我想，你肯定迫不及待的想“占有”它了，别急，今天我们就来学习一下，如何让刚体听我们的。

Box2D中控制一个刚体，让它乖乖的听我们的话，有三种方法：ApplyForce、ApplyImpulse和SetLinearVelocity。它们都是b2Body类的公共方法，而且它们都接收一个b2Vec2类型向量参数。关于向量的知识，请参考我之前发的文章"【游戏基础】向量基础".

1.力，循序渐进——ApplyForce

顾名思义，ApplyForce方法会在刚体上施加一个力。学过物理力学的同学都知道，F=ma，有了力F就有了加速度a，有了加速度，物体就会有速度，就会慢慢动起来。(但是不会立马动起来，因为力不会直接影响速度)。

举个简单的例子，小明推一个静止的箱子，箱子不会立马飞出去，而是慢慢的、越来越快的动起来(减速也一样)。

2.速度，叠加——ApplyImpulse

与ApplyForce不同，ApplyImpulse不会产生力，而是直接影响刚体的速度。通过ApplyImpulse方法添加的速度会与刚体原有的速度叠加，产生新的速度。

3.一触即发——SetLinearVelocity

setLinearVelocity与ApplyImpulse一样，直接影响刚体的速度。不一样的是，setLinearVelocity添加的速度会覆盖刚体原有的速度。不过，在SetLinearVelocity方法不会自动唤醒sleeping的刚体，所以在调用该方法之前，记得将刚体body.wakeUp()一下。

在下面的实例的右上角，任意选择其中一种方法，交替按下键盘左右方向键，查看三种方法的区别。

[Box2D]让刚体听我的——ApplyForce、ApplyImpulse、SetLinearVelocity 

关于三个方法的用法，源代码中已经有详细的备注，我就不再解释了：

  1. package
  2. {
  3.     import com.bit101.components.Panel;
  4.     import com.bit101.components.RadioButton;
  5.     import com.bit101.components.Window;

  7.     import Box2D.Common.Math.b2Vec2;
  8.     import Box2D.Dynamics.b2Body;
  9.     import Box2D.Dynamics.b2World;
  10.     import flash.display.Sprite;
  11.     import flash.events.Event;
  12.     import flash.events.KeyboardEvent;
  13.     import flash.ui.Keyboard;

  15.     /**
  16.      * http://www.ladeng6666.com
  17.      * @author ladeng6666
  18.      */
  19.     public class Main extends Sprite
  20.     {
  21.         //创建世界的基本元素
  22.         private var world:b2World;
  23.         private var debugSprite:Sprite;
  24.         private var body:b2Body;

  26.         private var vector:b2Vec2 = new b2Vec2();
  27.         private var currentMethod:String = "ApplyForce";

  29.         public function Main()
  30.         {
  31.             world=LDEasyBox2D.createWorld();
  32.             debugSprite=LDEasyBox2D.createDebug(world);
  33.             addChild(debugSprite);

  35.             setWrapWalls();

  37.             //创建矩形刚体
  38.             body = LDEasyBox2D.createBox(world, stage.stageWidth / 2, 0, 30, 30);
  39.             //侦听事件
  40.             addEventListener(Event.ENTER_FRAME, loop);
  41.             stage.addEventListener(KeyboardEvent.KEY_DOWN, onStageKeyDown);
  42.             stage.addEventListener(KeyboardEvent.KEY_UP, onStageKeyUp);

  44.             setUI();
  45.         }

  47.         private function setWrapWalls():void
  48.         {
  49.             //创建左边的墙
  50.             LDEasyBox2D.createBox(world, 0, stage.stageHeight / 2, 10, stage.stageHeight, true);
  51.             //创建右边的墙
  52.             LDEasyBox2D.createBox(world, stage.stageWidth, stage.stageHeight / 2, 10, stage.stageHeight, true);
  53.             //创建地面，
  54.             LDEasyBox2D.createBox(world,stage.stageWidth/2,stage.stageHeight,stage.stageWidth,10,true);
  55.         }

  57.         private function onStageKeyUp(e:KeyboardEvent):void
  58.         {
  59.             //清除速度或力
  60.             vector.SetZero();
  61.         }

  63.         private function onStageKeyDown(ke:KeyboardEvent):void
  64.         {
  65.             switch (ke.keyCode) {
  66.                 case Keyboard.LEFT:
  67.                     vector.x = -15;
  68.                     break;
  69.                 case Keyboard.RIGHT:
  70.                     vector.x = 15;
  71.                     break;
  72.             }
  73.             trace(currentMethod);
  74.             switch (currentMethod) {
  75.                 case "ApplyForce":
  76.                     //在刚体上施加vector压力。
  77.                     //body.GetWorldCenter()方法用来获取刚体的重心
  78.                     body.ApplyForce(vector, body.GetWorldCenter());
  79.                     break;
  80.                 case "ApplyImpulse":
  81.                     //为刚体添加速度
  82.                     body.ApplyImpulse(vector, body.GetWorldCenter());
  83.                     break;
  84.                 case "SetLinearVelocity":
  85.                     //唤醒刚体
  86.                     body.WakeUp();
  87.                     //设置刚体的线性速度
  88.                     body.SetLinearVelocity(vector);
  89.                     break;
  90.             }            

  92.         }

  94.         private function loop(e:Event):void
  95.         {
  96.             world.Step(1 / 30, 10);
  97.         }

  99.         //下面的方法用来创建UI
  100.         private function setUI():void
  101.         {
  102.             var panel:Panel = new Panel(stage, 400, 10);
  103.             panel.width = 100;
  104.             panel.height = 60;
  105.             var radio1:RadioButton = new RadioButton(panel, 5, 5, "ApplyForce", true,onRadioChange);
  106.             var radio2:RadioButton = new RadioButton(panel, 5, 25, "ApplyImpulse", false,onRadioChange);
  107.             var radio3:RadioButton = new RadioButton(panel, 5, 45, "SetLinearVelocity", false,onRadioChange);
  108.         }
  109.         //侦听UI中的radio按钮变更事件
  110.         private function onRadioChange(e:Event):void {
  111.             currentMethod = e.target.label;
  112.         }
  113.     }

  115. }
复制代码
标签：

相关文章