@echo off
mode con cols=35 lines=6 & color 5B
title 开机连接宽带--设置工具 QQ1009693258
echo 请稍候...
VER|FIND "版本 6">nul
if %errorlevel%==0 goto cwin7
if %errorlevel%==1 goto cXP
:cwin7
if exist "%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup\宽带连接.cmd" (goto xuanze) else (goto step1)
:cXP
if exist "%USERPROFILE%\「开始」菜单\程序\启动\宽带连接.cmd" (goto xuanze) else (goto step1)
:xuanze
cls
echo 请问您要进行什么操作？
echo 1.我要重新设置开机连接宽带
echo 2.我要取消设置开机连接宽带
set /p numb=请输入对应序号然后【回车】：
if "%numb%"=="" cls&echo 输入不能为空!&ping -n 2 127.0.0.1>nul&%0
if %numb%==1 goto step1
if %numb%==2 goto xiezai
cls
echo 输入无效!&ping -n 2 127.0.0.1>nul&%0
:xiezai
VER|FIND "版本 6">nul
if %errorlevel%==0 goto xwin7
if %errorlevel%==1 goto XXP
:xwin7
if exist "%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup\宽带连接.cmd" (del "%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup\宽带连接.cmd") else (goto xwin71)
cls
echo 已取消开机自动连接宽带！
echo 若要再次设置开机连接宽带请重新运行本程序
echo 按任意键退出
pause>nul
exit
:xwin71
cls
echo 取消失败！文件被重命名、移动或删除！
echo 按任意键退出
pause>nul
exit
:XXP
if exist "%USERPROFILE%\「开始」菜单\程序\启动\宽带连接.cmd" (del "%USERPROFILE%\「开始」菜单\程序\启动\宽带连接.cmd") else (goto xxp1)
cls
echo 已取消开机自动连接宽带！
echo 若要再次设置开机连接宽带请重新运行本程序
echo 按任意键退出
pause>nul
exit
:xxp1
cls
echo 取消失败！文件被重命名、移动或删除！
echo 按任意键退出
pause>nul
exit
:step1
cls
echo 请按要求输入数据然后按【回车】
echo 【第1/3步】
set usrname=
set /p usrname=宽带帐号:
if "%usrname%"=="" cls&echo 输入不能为空!&ping -n 2 127.0.0.1>nul&goto step1
:step2
cls
echo 【第2/3步】
set psswrd=
set /p psswrd=宽带密码:
if "%psswrd%"=="" cls&echo 输入不能为空!&ping -n 2 127.0.0.1>nul&goto step2
cls
echo 请您仔细阅读接下来的文字提示
echo 按任意键继续
pause>nul
:step3
mode con cols=60 lines=18 & color 5B
cls
set kdname=
echo 【第3/3步】
echo ------------------------------------------------------------
echo 获得本机宽带连接点名称的方法：
echo 1. 打开本机网络连接管理，然后在“宽带”栏中找到带有“WAN微
echo 型端口”描述的宽带连接点，将其名称填入下方，XP系统中默
echo 认为“宽带连接”，但也可能被更改，具体名称请以本机为准
echo 2. 不输入直接【回车】则打开网络连接管理,找到“宽带”栏查看
echo 本机宽带连接点名称；
echo 3. 输入H(不区分大小写)然后按【回车】可查看网络帮助；
echo 4. 如果宽带连接点名称含有汉字无法输入，请复制其名称然后用
echo 鼠标右键粘贴到下方。
echo ------------------------------------------------------------
set /p kdname=输入本机宽带连接点名称:
if "%kdname%"=="" start ncpa.cpl&goto step3
if /i "%kdname%"=="h" start http://hi.baidu.com/laiwei01/blog/item/ef2d984a93db7e3a09f7efcd.html&goto step3
cls
mode con cols=35 lines=7 & color 5B
ECHO 正在验证...
rasdial "%kdname%" %usrname% %psswrd%>nul
if not %errorlevel%==0 cls&echo 宽带帐号、密码或宽带名称输入有误！&echo 请确认网线已连接，然后按任意键重新输入&pause>nul&goto step1
cls
echo 提示：本程序即将设置宽带连接为开机启动，如遇安全软件阻止,请选择允许，否则将无法成功设置开机自动连接宽带
echo --------------------------------
echo 按任意键继续
pause>nul
cls
echo 正在处理...
echo 如遇安全软件阻止请允许。
echo @echo off>宽带连接.cmd
echo title 宽带连接>>宽带连接.cmd
echo mode con cols=20 lines=3 ^& color 5B>>宽带连接.cmd
echo set /a a=^0>>宽带连接.cmd
echo set ech=正在连接宽带>>宽带连接.cmd
echo :kd>>宽带连接.cmd
echo cls>>宽带连接.cmd
echo set /a a+=^1>>宽带连接.cmd
echo if %%a%% geq 2 set ech=失败！重试中>>宽带连接.cmd
echo echo %%ech%%[%%a%%]...>>宽带连接.cmd
echo rasdial "%kdname%" %usrname% %psswrd%>>宽带连接.cmd
echo if %%a%%==3 exit>>宽带连接.cmd
echo if not %%errorlevel%%==0 (goto kd) else (exit)>>宽带连接.cmd
ping -n 4 127.0.1>nul
VER|FIND "版本 6">nul
if %errorlevel%==0 goto win7
if %errorlevel%==1 goto XP
:win7
move /y 宽带连接.cmd "%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup\"
if %errorlevel%==0 (cls&echo 恭喜您，设置成功！要体验请重启电脑&pause>nul&exit) else (del 宽带连接.cmd&cls&echo 设置失败！可能是安全软件阻止所致。&pause>nul&exit)
:XP
move /y 宽带连接.cmd "%USERPROFILE%\「开始」菜单\程序\启动\"
if %errorlevel%==0 (cls&echo 恭喜您，设置成功！要体验请重启电脑&pause>nul&exit) else (del 宽带连接.cmd&cls&echo 设置失败！可能是安全软件阻止所致。&pause>nul&exit)
::代码结束